X: 0
T: The MacPhersons of Edinburgh
T: 8x32S3
C: MacPherson Clan
B: Scottish Country Dances in Diagrams. ed.6,7,8
R: strathspey
K:


X: 1
P: Miss Isabella MacPherson Grant's Strathspey
C: William Marshall
N: William Marshall, v.1, p.51
R: strathspey
Z: 1997 by John Chambers <jc:trillian.mit.edu>
M: C
L: 1/16
K: F
a2 \
| "F"cc3 (c3B) A3c f4 | "Bb"dd3 (d3c) "C7"d3f g3a \
| "F"f3F A3F "(Dm)"(Ac3) f4 | "Gm"d3g "C7"(fe)dc "F"f6 :|
g2 \
| "F"a3f (ag)fe "(Dm)"f2c2 f4 | "Gm"b3g (ba)gf "C7"(ef)ga g2fg \
| "F"a3f (ag)fe "(Dm)"f2c2 f4 | "C7"c3f efge "F"f6 |]
g2 \
| "F"a3f (ag)fe "(Dm)"f2c2 f4 | "Gm"b3g (ba)gf "C7"(ef)ga g2fg \
| "Bb"(ba)gf "C7"g3e "F"f3c "Bb"(df3) | "C7"c3f efge "F"f6 |]


X: 2
P: the Marquis of Huntly's Strathspey
C: William Marshall
N:
N: Caledonian Companion, p.86
N: Hunter 174
N: Skye, p.123
N: First published in 1781, in Marshalls "Collection of Strathspey Reels" as
N: the "Marquis of Huntly's Reel"; published in 1822 as a strathspey.
Z: 1997 John Chambers <jc:trillian.mit.edu>
M: 4/4
L: 1/8
K: GDorian
F \
|  "Gm"D<G {A}G>F D<G G>A | "F"F>G A>B c/B/A/G/ F<A \
|  "Gm"D<G {A}G>F D<G G>g | "F"f>c "(D7)"d/c/B/A/ "Gm"B<G G :|
d \
| "Gm"g>a b>g d<g b>g | "F"a/g/f/d/ c>e f<c a>f \
| "Gm"g>a b>g d<g b>g | b/a/g/f/ "D7"d>^f "Gm"~g3 |]
d \
| "Gm"g>a b>g "(D)"a<^f "Gm"g>e | "F"f>d c<f A<F c>F \
| "Gm"D<G {A}G>F D<G G>g | "F"f>c "(D7)"d/c/B/A/ "Gm"B<G G |]



X: 3
P: Mr. Oswald of Auchincruive (the Balquidder Strathspey)
R: strathspey
B: RSCDS 24-2
B: RSCDS 14-__
Z: 1997 by John Chambers <jc:trillian.mit.edu>
N: There is also a "Miss Oswald of Auchincruive" by Nathaniel Gow, a completely different tune.
M: C
L: 1/8
K: G
D \
| "G"G>A B<d B>A B<g | d<B A>G "D7"F<A A>B \
| "G"G/A/B B<B "(Em)"B>A B<g | "D7"d<B A>G "G"D<G G :|
f \
| "G"g>a b<g "D7"f<d a<f | "G"g/f/g/a/ b>g "D7"f<a a>f \
| "G"g>a b<g "D7"f<d a<f | "C"g<e "D7"d>c "G"B<G G |]
f \
| "G"g>a b<g "D7"f<d a<f | "G"g/f/g/a/ b>g "D7"f<a a>f \
| "G"g<b "D"a<b "Em"g<a "Bm"f<g | "Am"e<a "D7"f<d "G"g>a g |]


X: 4
P: the Glen Tromie Strathspey
C: William Marshall
Z: John Chambers <jc:trillian.mit.edu>
N: Marshall's v.1, p.45
M: 4/4
L: 1/8
K: C
e/f/ | "C"g-<c "(G7)"e>d "C"c3 e/f/ | g-<c a>c "G7"B-<d de/f/ \
     | "C"g-<c "(G7)"e>d "Am"c2- c/B/A/G/ | "F"A/B/c/A/ "G7"B/c/d/B/ "C"Gc c :|
G/F/ | "C"E>c Gc Ec Gc | "Am"e>d c/d/e/c/ "G7"dD DG/F/ \
     | "C"E>c Gc Eg ec | "F"A>f "G7"dB "C"ec c |]
G/F/ | "C"E>c Gc Ec Gc | "D7"e>d c/d/e/c/ "G7"dD DG/F/ \
     | "C"E>G cE "Dm"FA df | "G7"e/f/g/a/ g/f/e/d/ "C"ec c |]